Windows update via vbs

I cant recall where I found the code, but it used to work fine. I have not edited it in any fashion and don't know why it no longer works. I had to do recovery disk installation and was looking for this to run again.

'ServerSelection values
ssDefault = 0
ssManagedServer = 1
ssWindowsUpdate = 2
ssOthers        = 3

'InStr values
intSearchStartChar = 1

Dim strTitle

Set updateSession = CreateObject("Microsoft.Update.Session")
Set updateSearcher = updateSession.CreateupdateSearcher()

updateSearcher.ServerSelection = ssWindowsUpdate
Set searchResult = updateSearcher.Search("IsInstalled=0 and Type='Software'")

WScript.Echo "List of applicable items on the machine:"

For I = 0 To searchResult.Updates.Count-1
    Set update = searchResult.Updates.Item(I)
    WScript.Echo I + 1 & "> " & update.Title
Next

If searchResult.Updates.Count = 0 Then
    WScript.Echo "There are no applicable updates."
    WScript.Quit
End If

WScript.Echo vbCrLf & "Creating collection of updates to download:"

Set updatesToDownload = CreateObject("Microsoft.Update.UpdateColl")

For I = 0 to searchResult.Updates.Count-1
    Set update = searchResult.Updates.Item(I)
    addThisUpdate = False
    If update.InstallationBehavior.CanRequestUserInput = True Then
        WScript.Echo I + 1 & "> skipping: " & update.Title & _
            " because it requires user input"
    Else
        If update.EulaAccepted = False Then
            WScript.Echo I + 1 & "> note: " & update.Title & _
                " has a license agreement that must be accepted:"
            WScript.Echo update.EulaText
            WScript.Echo "Do you accept this license agreement? (Y/N)"
            ''strInput = WScript.StdIn.ReadLine
            strInput = "Y"
            WScript.Echo
            If (strInput = "Y" Or strInput = "y") Then
                update.AcceptEula()
                addThisUpdate = True
            Else
                WScript.Echo I + 1 & "> skipping: " & update.Title & _
                    " because the license agreement was declined"
            End If
        Else
            addThisUpdate = True
        End If
    End If
    If addThisUpdate = True Then
        WScript.Echo I + 1 & "> adding: " & update.Title
        updatesToDownload.Add(update)
    End If
Next

If updatesToDownload.Count = 0 Then
    WScript.Echo "All applicable updates were skipped."
    WScript.Quit
End If

WScript.Echo vbCrLf & "Downloading updates..."

Set downloader = updateSession.CreateUpdateDownloader()
downloader.Updates = updatesToDownload
downloader.Download()

Set updatesToInstall = CreateObject("Microsoft.Update.UpdateColl")

rebootMayBeRequired = False

WScript.Echo vbCRLF & "Successfully downloaded updates:"

For I = 0 To searchResult.Updates.Count-1
    set update = searchResult.Updates.Item(I)
    If update.IsDownloaded = True Then
        WScript.Echo I + 1 & "> " & update.Title
        updatesToInstall.Add(update)
        If update.InstallationBehavior.RebootBehavior > 0 Then
            rebootMayBeRequired = True
        End If
    End If
Next

If updatesToInstall.Count = 0 Then
    WScript.Echo "No updates were successfully downloaded."
    WScript.Quit
End If

If rebootMayBeRequired = True Then
    WScript.Echo vbCrLf & "These updates may require a reboot."
End If

WScript.Echo  vbCrLf & "Would you like to install updates now? (Y/N)"
''strInput = WScript.StdIn.ReadLine
strInput = "Y"
WScript.Echo

If (strInput = "Y" Or strInput = "y") Then
    WScript.Echo "Installing updates..."
    Set installer = updateSession.CreateUpdateInstaller()
    installer.Updates = updatesToInstall
    Set installationResult = installer.Install()

    'Output results of install
    WScript.Echo "Installation Result: " & _
    installationResult.ResultCode
    WScript.Echo "Reboot Required: " & _
    installationResult.RebootRequired & vbCRLF
    WScript.Echo "Listing of updates installed " & _
    "and individual installation results:"

    For I = 0 To updatesToInstall.Count - 1
        WScript.Echo I + 1 & "> " & _
        updatesToInstall.Item(i).Title & _
            ": " & installationResult.GetUpdateResult(i).ResultCode
    Next
End If

When I run it, it gives me a list of updates, and I can select to download and install but at the end I get an error.

Line: 77 char: 1
error: 0x80240044
code:80240044
source: (null)

Tried to Google

https://www.google.com/search?newwindow=1&q=vbs+error+%22802400044%22&sa=X&ved=2ahUKEwjVws2lquXcAhUHxFQKHfq2Dx0Q5t4CMAB6BAgBEA8&biw=939&bih=662

Does this look familiar to anyone? Anyone having any luck getting it to run?